EnigmA Amiga Run 1996 March/EnigmA AMIGA RUN 05 (1996)(G.R. Edizioni)(IT)[!][issue 1996-03][Skylink CD IV].iso/earcd/editor/chktex.lha/chktex/ChkTeX.install

Text File | 1996-01-25 | 8KB | 489 lines

;
;  ChkTeX.install v1.2, installs the ChkTeX program
;  Copyright (C) 1995-96 Jens T. Berger Thielemann
;
;  This program is free software; you can redistribute it and/or modify
;  it under the terms of the GNU General Public License as published by
;  the Free Software Foundation; either version 2 of the License, or
;  (at your option) any later version.
;
;  This program is distributed in the hope that it will be useful,
;  but WITHOUT ANY WARRANTY; without even the implied warranty of
;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;  GNU General Public License for more details.
;
;  You should have received a copy of the GNU General Public License
;  along with this program; if not, write to the Free Software
;  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
;
;  Contact the author at:
;      Jens Berger
;      Spektrumvn. 4
;      N-0666 Oslo
;      Norway
;      E-mail: <[e-mail]>
;
;
;

(procedure
    GetOS
    (
        (set
            tmpscript
            "T:ChkTeX.install.tmpscript"
        )

        (textfile
            (dest tmpscript)
            (append
                "failat 31\n"
                "Version exec.library VERSION 36\n"
                "If ERROR\n"
                "    SetEnv Installer-Result 10\n"
                "Else\n"
                "    If WARN\n"
                "        SetEnv Installer-Result 5\n"
                "    Else\n"
                "        SetEnv Installer-Result 0\n"
                "    Endif\n"
                "Endif\n"
            )
            (safe)
        )

        (execute
            tmpscript
            (safe)
        )

        (set
            HasNewOS
            (getenv "Installer-Result")
        )

        (delete tmpscript)

        (if
            (=
                HasNewOS
                0
            )
            (set
                ConfigPath
                "ENVARC:"
            )
            (set
                ConfigPath
                "S:"
            )
        )
    )
)


(set @app-name "ChkTeX")

(welcome)

(complete 0)

(message
    "Welcome to the ChkTeX installation script. "
    "Please note that it may be wise to run the ChkTeX.sum "
    "script before installing any of the programs, or better "
    "still, use PGP and MD5SUM manually.\n"
    "Before taking the program in use, please read the COPYING file; "
    "it applies to this script as well as the remaining parts of the "
    "package. In short:\n NO WARRANTIES WHATSOEVER.\n\n"
    "Copyright © 1995-96\nJens T. Berger Thielemann\n<[e-mail]>"
)

(complete 10)

(set
    @default-dest
    (askdir
        (prompt "Where do you wish ChkTeX installed?")
        (default "C:")
        (help
            "  You can here select where you wish to install the "
            "main ChkTeX executable program.\n\n"
            @askdir-help
        )
    )
)

(complete 20)

(copyfiles
    (source "ChkTeX")
    (dest @default-dest)
    (infos)
)

(complete 30)

(GetOS)

(complete 40)

(if
    (exists
        (tackon
            ConfigPath
            ".chktexrc"
        )
    )
    (
        (set
            ConfigSum
            (getsum
                (tackon
                    ConfigPath
                    ".chktexrc"
                )
            )
        )
        (debug ConfigSum)
        (set
            ModifiedConfig
            (and
                (<>
                    ConfigSum
                    -1288016259
                )
                (<>
                    ConfigSum
                    1351485522
                )
            )
        )
    )
)

(complete 50)

(if
    (=
        ModifiedConfig
        1
    )
    (
        (set
            ModWarn
            "\nThere exists a *modified* version of the .chktexrc file already."
        )
        (set
            ModDefault
            0
        )
    )
    (
        (set
            ModWarn
            ""
        )
        (set
            ModDefault
            1
        )
    )
)

(complete 60)

(if
    (=
        @user-level
        2
    )
    (set
        install
        (askbool
            (prompt "Install environment files?" ModWarn)
            (help
                "  If you select `yes', the default environment files will "
                "be installed. They will initialize ChkTeX to a `normal' "
                "behaviour, and give a good starting-point for "
                "modification.\n"
                "  However, if you've already installed an earlier version of "
                "ChkTeX, and modified the .chktexrc file, you will probably not "
                "want to overwrite that one. However, you should still take a "
                "look at the included .chktexrc, to be introduced to the new "
                "keywords that were introduced."
            )
            (default ModDefault)
        )
    )
    (set
        install
        (NOT ModifiedConfig)
    )
)

(complete 70)

(if
    (=
        install
        1
    )
    (
        (copyfiles
            (source ".chktexrc")
            (dest ConfigPath)
        )

        (if
            (=
                ConfigPath
                "ENVARC:"
            )
            (copyfiles
                (source ".chktexrc")
                (dest "ENV:")
            )
        )
    )
)

(complete 75)

(if
    (exists
        "HELP:"
        (noreq)
    )
    (set
        docdest
        "HELP:"
    )
    (set
        docdest
        @default-dest
    )
)


(copyfiles
    (source "")
    (dest docdest)
    (choices
        "COPYING"
        "ChkTeX.readme"
        "ChkTeX.dvi"
        "ChkTeX.ps"
    )
    (prompt "Which documentation files do you wish to install?")
    (help
        "  If you would like to have the documentation online, you have "
        "the possibility here. It might be nice for future reference.\n"
        "  As you may know, the .dvi file is in the Device Independent "
        "format; the .ps file is in PostScript. Please select those "
        "fitting your decoding software.\n"
        "  The remaining files are plain iso-8859-1 encoded text files.\n\n"
        @copyfiles-help
    )
    (confirm)
    (infos)
)

(complete 80)

(if
    (or
        (exists
            "REXX:"
            (noreq)
        )
        (=
            @user-level
            2
        )
    )
    (copyfiles
        (source "")
        (dest "REXX:")
        (choices
            "ChkTeX.rexx"
            "ChkTeX.ced"
            "ChkTeX.ged"
        )
        (prompt "Which parts of the SCMSG/ARexx interface should be installed?")
        (help
            "  If you've got SCMSG (included in the SAS/C package) and "
            "ARexx installed, these scripts will make the use much more "
            "comfortable.\n"
            "  To use any of these, you must install the `ChkTeX.rexx' "
            "script.\n"
            "  In addition, you may wish to install `ChkTeX.ced' or `ChkTeX.ged' "
            "if you are using respectively CygnusED or GoldED to "
            "edit your LaTeX files.\n"
            "  These interfaces may of course be improved even more, "
            "by making the editor's screen public, and installing the "
            "programs on a hotkey.\n\n"
            @copyfiles-help
        )
        (confirm)
        (infos)
    )
)

(complete 90)

(if
    (or
        (exists
            "USR:lib/perl"
            (noreq)
        )
        (=
            @user-level
            2
        )
    )
    (copyfiles
        (source "ChkTeX.pl")
        (dest "USR:lib/perl")
        (choices
            "ChkTeX.pl"
        )
        (prompt "Install Emacs (via Perl) interface?")
        (help
            "  If you are using Emacs to edit your files, the compile "
            "package expects the error reports to come in a UNIX-like way. "
            "A Perl script is provided as an translator. To use this, you'll "
            "have to have both Perl and Emacs (not MicroEmacs) installed.\n\n"
            @copyfiles-help
        )
        (confirm)
        (infos)
    )
)

(complete 100)

(exit
    "The installation of ChkTeX is complete. To enhance the program "
    "function, please take a look at the .chktexrc file, located in the "
    "`" ConfigPath "' directory.\n\n"
    "Have fun."
)

; (if
;     (=
;         2
;         (exists
;             "LOCALE:"
;             (noreq)
;         )
;     )
;     (
;         (set
;         catalog
;             (select
;                 (askchoice
;                     (prompt "Which language do you wish to install?")
;                     (choices "English" "Norsk")
;                     (help
;                         "ChkTeX can support other languages than English, "
;                         "you can here select which one you would like.\n"
;                         "If your OS does not support languages (i.e. OS < 2.1),"
;                         "select 'English'."
;                         @askchoice-help
;                     )
;                     (default 0)
;                 )
;                 ""
;                 "norsk"
;             )
;         )
;
;         (if
;             (<>
;                 catalog
;                 ""
;             )
;             (copyfiles
;                 (source
;                     (cat
;                         "Catalogs/"
;                         catalog
;                         "/ChkTeX.catalog"
;                     )
;                 )
;                 (dest
;                     (cat
;                         "LOCALE:Catalogs/"
;                         catalog
;                     )
;                 )
;                 (infos)
;             )
;         )
;     )
; )
;

; (if
;     (=
;         @user-level
;         2
;     )
;     (if
;         (askbool
;             (prompt "Install ChkTeX C-source files?")
;             (help
;                 "  If you select `yes', the source code files of the "
;                 "project will be installed in a directory of your selection. "
;                 "This may be handy for future reference, or if you wish to "
;                 "hack a bit on ChkTeX for yourself. Please read the COPYING "
;                 "file before doing so, however."
;             )
;             (default 0)
;         )
;         (
;             (set
;                 sourcedest
;                 (askdir
;                     (prompt "Where do you want the source installed?")
;                     (default "sc:source/")
;                     (help
;                         "  You can here select where you wish to install the "
;                         "C source of the main ChkTeX executable program. "
;                         "A directory will be created there named ChkTeX.\n\n"
;                         @askdir-help
;                     )
;                 )
;             )
;             (set
;                 sourcedir
;                 (tackon
;                     sourcedir
;                     "ChkTeX
;             (tackon
;                 "s
;
;             (copyfiles
;                 (source "source/")
;                 (dest sourcedest)
;                 (choices
;                     "Workbench.c"
;                     "ChkTeX.h"
;                     "OpSys.c"
;                     "ChkTeX.c"
;                     "Resource.c"
;                     "Utility.c"
;                     "getopt.h"
;                     "getopt.c"
;                     "getopt1.c"
;                     "FindErrs.c"
;                 )
;                 (infos)
;             )
;         )
;     )
; )